VBScript reference

This page documents the built-in objects available exclusively in Remote Scripting (VBScript). These objects are not available in Python. In addition to regular automation objects created with CreateObject(), you can call Internal.CreateObject() to create the following objects.

Telnet

'Retrieve system info via Telnet
'This example code can be adapted to work
'with any device that supports the protocol

'Create internal Telnet object
set objTelnet = Internal.CreateObject("Telnet")

'Set host name and port
objTelnet.Host = Input.Current
objTelnet.Port = 23

'Make connection
objTelnet.Connect

'Wait for login prompt
objTelnet.WaitFor("login:")
'Then send username
objTelnet.Send("YourUserName" & vbCrLf)

'Wait for password prompt
objTelnet.WaitFor("password:")
'Then send password
objTelnet.Send("YourPassword" & vbCrLf)

'Wait for shell prompt
objTelnet.WaitFor("xsh>")
'Then send command
objTelnet.Send("show sys versions" & vbCrLf)

'Wait for shell prompt (when command finishes)
data = objTelnet.Recv("xsh>")

'Return data and disconnect
Output.Write data
objTelnet.Disconnect

Process

'This runs ping.exe, captures its output and extracts reported packet loss
'It can be adapted to execute any console programs and parse their output

'Create process object and execute ping
Set proc = Internal.CreateObject("process")
proc.execute("ping.exe " & Input.Current)

'Check ping exit code
If proc.ExitCode = 0 Then

	'Setup a regex object
	Set objRegex = New RegExp
	objRegex.IgnoreCase = True
	objRegex.Multiline = True
	objRegex.Global = True
	'Look for a string like (X% loss)
	objRegex.Pattern = "\((\d+%\s\w+)\)"

	'Traverse output lines
	For Each line in proc.output
		Set matches = objRegex.Execute(line)
		'Print matching data
		For Each match in matches
			Output.Write match.SubMatches(0)
		Next
	Next
Else
	Output.Write "Exit code " & proc.ExitCode
End If

DNS

'Resolve a name or IP address via DNS
'This example performs a reverse lookup

'Create internal DNS object
set dnsObj = Internal.CreateObject("dns")

'Optionally set DNS server
'dnsObj.Server = "x.x.x.x"

'Get PTR record for the current IP address
name = dnsObj.GetName(Input.Current, "ptr")

'Print out resolved name
Output.Write name

SNMP

'Create SNMP object and set target host
set objSnmp = Internal.CreateObject("snmp")
objSnmp.Host = Input.Current

'Use version 2 and get sysDescr
objSnmp.Query.Version = 2
objSnmp.Query.SetOID("1.3.6.1.2.1.1.1.0")
If objSnmp.SendRequest then
	'Success
	Output.Write objSnmp.Reply.Items(0).Value
End If

'Now get interface table.
'In SNMP v2/3 we can use bulk requests

objSnmp.Query.SetOID("1.3.6.1.2.1.2.2.1.2")
objSnmp.Query.MaxRepetitions = 10
objSnmp.Query.PDUType = &hA5
Do While objSnmp.SendRequest
	'Success
	For Each Item in objSnmp.Reply.Items

		'Break the loop if found a different OID
		If InStr(Item.OID, "1.3.6.1.2.1.2.2.1.2") = 0 Then
			Exit Do
		End if

		'Write interface name
		Output.Write Item.Value

		'Continue from the current OID
		objSnmp.Query.SetOID(Item.OID)
	Next
Loop

Remote namespace

You can invoke any named scan item from your script using the following functions:

Calling an item by its name executes the corresponding scan. For example:

'This script prints the Windows version retrieved via WMI.
winName = Remote.WMI("Windows Name")
Output.Write "This comes from WMI: " & winName